Windows en pc nuevo

[pimpolino]

Acabo de comprar un pc nuevo y viene w10 activado..... Pero como hago, para la próxima que formate el pc siga con el w10 activado?

 

[Jorge.S]

las licencias OEM se asocian a la ID de la placa base, mientras no cambies la placa base del portatil no hay problema, incluso puedes cambiar el disco duro que seguiras con tu licencia.

 

[FREEMAN]

Acabo de comprar un pc nuevo y viene w10 activado..... Pero como hago, para la próxima que formate el pc siga con el w10 activado?

Si vuelves a instalar la misma edición (Home, o Pro) no tienes que hacer nada,
simplemente eliges No tengo clave del producto

Por otro lado, si quieres saber si tu equipo es OEM y trae la clave incrustada en UEFI,
abre el Windows PowerShell (Administrador) Copia y pega el contenido del código,
y seguidamente presionas la tecla Enter a ver si te sale una clave de 25 dígitos.

wmic path softwarelicensingservice get OA3xOriginalProductKey

 

[pimpolino]

las licencias OEM se asocian a la ID de la placa base, mientras no cambies la placa base del portatil

Si vuelves a instalar la misma edición (Home, o Pro) no tienes que hacer nada,
simplemente eliges No tengo clave del producto

Por otro lado, si quieres saber si tu equipo es OEM y trae la clave incrustada en UEFI,
abre el Windows PowerShell (Administrador) Copia y pega el contenido del código,
y seguidamente presionas la tecla Enter a ver si te sale una clave de 25 dígitos.

wmic path softwarelicensingservice get OA3xOriginalProductKey

Sale originalproductkey....

 

[FREEMAN]

Sale originalproductkey....

A continuación te debería de salir 25 dígitos, por ejemplo → VK7JG-NPHTM-C97JM-9MPGT-3V66T
Si NO sale es que el equipo no es OEM.

Por el contrario, si ese equipo lo has comprado en una tienda de montaje, entonces es normal que no aparezca la clave,
pero de todas formas, cuando vuelvas a instalar Windows elige la misma edición y se activará automáticamente.

Si quieres saber; la clave, la ID del producto, y la edición de Win10, abre un Bloc de notas.
Copia y pega el siguiente script, y lo guardas en el Escritorio con el nombre Produkey.vbs

Option Explicit

Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData
End If



'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
           Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
 
  
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")
    'Create a text file on desktop
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function

Cuando te aparezca en el Escritorio Ejecuta dicho archivo